perl-gimp

Gimp ist das (!) freie Grafikbearbeitungsprogramm überhaupt. Einen Vergleich mit Photoshop braucht es vom Funktionsumfang nicht zu scheuen, kostet dafür aber nix und steht unter der GPL. Ein weitere Vorteil ist die beliebige Erweiterbarkeit durch Skripte. Dies ermöglicht es jedem, Gimp für sich und andere auszubauen. Als Standard-Skript-Sprache ist hierfür Scheme vorgesehen. Über Vor- und Nachteile dieser Sprache kann man denken was man will, für alle Perl-Freunde wurde jedenfalls eine Gimp-Perl-Erweiterung geschrieben.

Wie man diese nutzt, und sich somit bestimmte Arbeiten erleichtern kann möchte ich hier erklären, wobei zumindest grundlegende Perl-Kenntnisse vorausgesetzt werden. Ein typisches Beispiel sind grafische Buttons für eine Homepage. Möchte man diese per Hand erstellen, so muss man jeden Button einzeln machen, und das obwohl doch bis auf den Text alle gleich aussehen sollen. Nunja, auf Dauer sicher langweilig. Richtig ärgerlich wird das ganze beispielsweise dann, wenn die Buttons plötzlich etwas anders aussehen sollen (zum Beispiel eine andere Hintergrundfarbe haben sollen). Doch zum Glück kann man so etwas ja auch mit einem Skript erledigen...

Ich habe dieses Tutorial mit Gimp 1.2 unter Linux getestet, an Erfahrungen mit anderen Versionen bin ich natürlich interessiert. Wer das hier also unter anderen Bedingungen probiert hat, kann sich gerne mit Erfolgen oder Problemen bei mir unter <michael at binaervarianz dot de> melden.

Was wir brauchen

Erst einmal muss die Perl-Erweiterung für Gimp installiert sein. Diese ist bei jeder größeren Linux-Distribution dabei, bei Debian heißt das Paket gimp1.2-perl (für Gimp Version 1.2), woanders sicher ähnlich. Außerdem brauchen wir das Perl-Modul Gimp. Es gehört zu den Standard-Modulen und ist deshalb bei Debian im Paket perl-modules enthalten. Alternativ kann man es sich auch bei cpan.org besorgen.

In unser Skript eingebunden sieht das ganze dann wie folgt aus:

 #!/usr/bin/perl -w
 
 use strict;
 use Gimp ":auto";
 use Gimp::Fu;

Neben dem obligatorischen "strict", brauchen wir das Haupt-Modul "Gimp". Mit ":auto" holen wir alle später benötigten Funktionen und Konstanten in unseren Namesraum. "Gimp::Fu" setzt auf "Gimp" auf und stellt eine relativ einfache Schnittstelle zur Verfügung.

Grundlegendes

Für alles, was man mit Gimp so machen kann gibt es eine Funktion. Eine Übersicht über diese Funktionen findet man in Gimp selbst im Menü: Xtns - PDB-Explorer. Alternativ kann auch der DB-Browser verwendet werden, wobei mir ersterer besser gefällt. Zu jeder Funktion werden die Ein- und Ausgabeparameter, eine Beschreibung sowie einige andere Angaben angezeigt. Sucht man beispielsweise nach gimp_image_new, so findet man folgende Einträge:

Die Parameter dieser Funktion haben die Typen INT32 und IMAGE. Insgesamt gibt es 22 solcher Typen, wobei manche dasselbe meinen - die folgende Übersicht empfehle ich erst einmal nur zu überfliegen, um später bestimmte Typen nachzuschauen:

Das erste Skript

Unser erstes Gimp-Skript wird ein Bild erzeugen, dessen Größe und Hintergrundfarbe festgelegt werden kann (atemberaubend - ich weiß ;-). Es besteht aus 2 großen Teilen, dem Register-Teil und einer Subroutine. Im Register-Teil werden allgemeine Dinge zum Skript festgelegt, während die Subroutine die auszuführenden Schritte beinhaltet.

 #!/usr/bin/perl -w
 
 use strict;
 use Gimp ":auto";
 use Gimp::Fu;
 
 sub bild_hg {
     # übergebene Werte in einzelne Variablen schreiben
     my ($size, $color) = @_;
     
     # neues Bild erzeugen
     my $img = gimp_image_new($size, $size, RGB);
     
     # neue Ebene erzeugen
     my $layer = gimp_layer_new($img, $size, $size,
                   RGB_IMAGE, "Ebene 1", 100, 0);
     
     # Ebene dem Bild hinzufügen
     gimp_image_add_layer($img, $layer, -1);
     
     # Hintergrundfarbe setzen
     gimp_palette_set_background($color);
     
     # Ebene mit Hintergrundfarbe einfärben
     gimp_edit_fill($layer, BG_IMAGE_FILL);
     
     # Bild zurückgeben
     return $img;
 }
 
 register
   # Name
   "Bild mit HG-Farbe"
   # Beschreibung
   "Ein Bild mit festlegbarer Hintergrund-Farbe.",
   # Hilfetext
   "hier wohl nicht notwendig",
   # Autoren-Name
   "Michael Pradel",
   # Copyright
   "Michael Pradel",
   # Datum
   "13-07-2002",
   # Pfad
   "<Toolbox>/Xtns/Perl-Fu/Bild-HG",
   # Bildarten
   "*",
   # zu übergebene Werte
   [
    [PF_INT, "size", "Bildgroesse", 100],
    [PF_COLOR, "color", "Hintergrundfarbe", '#71a5f2']
   ],
   # Aufruf der Subroutine
   \&bild_hg;
 
 exit main();

Der Register-Teil

Der Register-Teil wird durch das Schlüsselwort register am Anfang gekennzeichnet. Hier werden durch Komma getrennt 10 Angaben zum Skript gemacht. Die Zeilen 31-42 sollten selbsterklärend sein, als sechte Register-Angabe (Zeile 44) wird der Pfad erwartet, wo das Plugin zu finden sein soll. Dieser kann entweder mit <Toolbox> beginnen, also im Gimp-Hauptfenster, oder mit <Image>, also in dem Menü was sich öffnet, wenn man mit der rechten Maustaste auf das Bild klickt. Der achte Teil (Zeile 46) gibt an, für welche Bildarten das Plugin verfügbar sein soll (z.B. RGB), "*" meint alle.

Die neunte Angabe ist der wohl komplizierteste Teil des Register-Teils. Hat man es einmal verstanden aber auch nicht weiter schlimm. Hier wird angegeben, welche Werte beim Aufruf des Skripts vom Benutzer angegeben werden können. Sowohl das gesamte Übergabe-Array, als auch jedes zu übergebende Element werden durch eckige Klammern eingegrenzt. Für jedes Element sind (mindestens) 4 Angaben zu machen:

• der Typ des Wertes (siehe Übersicht)
• ein Name
• eine Beschreibung (das was der Benutzer sieht)
• ein Standard-Wert

Die Subroutine

Bevor wir mit den einzelen Schritten beginnen, müssen wir die vom Benutzer festgelegten Werte in einzelne Variablen kopieren (Zeile 9). Alle in Punkt neun des Register-Teils festgelegten Werte befinden sich in der richtigen Reihenfolge im Array @_. Nun rufen wir die bereits oben vorgestellte Funktion gimp_image_new auf (Zeile 12). Sie erwartet zwei Parameter zur Größe (horizontal und vertikal), sowie die Art des Bildes (bei uns RGB). Als Rückgabewert erhalten wir die ID des Bildes, welche wir in $img speichern.

Als nächstes erstellen wir eine neue Ebene (Zeile 15), und fügen diese unseren Bild hinzu (Zeile 18). Dieser Schritt ist notwendig, da ein erstelltes Bild standardmäßig keine Ebene hat. Die genaue Syntax der einzelnen Funktionen könnt ihr im PDB-Browser nachschauen.

Nun setzen wir noch die Hintergrundfarbe auf den vom Benutzer gewünschten Wert (welcher ja in $color gespeichert ist), und füllen unser Bild damit. Zum Schluss muss noch das Bild an Gimp zurückgegeben werden (Zeile 27).

Einbinden in Perl

Unser Skript muss jetzt noch ausführbar gemacht werden. Außerdem empfiehlt sich immer der Perl-Syntax-Check:

Anschließend kopiert man das Skript ins Verzeichnis ./gimp-1.2/plug-ins im Home-Verzeichnis. Alternativ kann man auch den offiziellen Weg über gimptool wählen. Hierzu muss man allerdings erst die Gimp-Entwickler-Pakete installieren (bei Debian libgimp1.2-dev), und kann anschließend mit

bzw. falls das Plugin für alle User verfügbar sein soll

für die korrekte Einbindung des Skripts sorgen. Der erste Weg ist einfacher und reicht für den Anfang völlig aus.

Jetzt müssen wir nur noch Gimp (neu)starten und können das Plugin starten. Es befindet sich in dem von uns angegebenen Pfad (<Toolbox>/Xtns/Perl-Fu/Bild-HG). Wenn alles geklappt hat bekommen wir folgendes Bild als Ergebnis:

Button mit Schatten

Wie am Ergebnis zu sehen ist, war das letzte Beispiel recht einfach. Nun wollen wir ein etwas umfangreicheres Beispiel durchgehen, dass den praktischen Nutzen von Perl-Skripten in Gimp schon eher verdeutlicht: ein Button mit Schatten.

Das Plugin ist so geschrieben, dass der Anwender die Größe, die verwendeten Farben und natürlich den Button-Text bestimmen kann. Es ist grundsätzlich für einen einzelnen Button gedacht, man kann aber mit einer einfachen Schleife auch mehrere Buttons mit verschiedenen Texten erstellen.

 #!/usr/bin/perl -w
 
 use strict;
 use Gimp ":auto";
 use Gimp::Fu;
 
 sub button {
     my ($hsize, $vsize, $bgcolor, $frcolor, $font, $text) =
        @_;
     
     # neues Bild erzeugen
     my $img = gimp_image_new($hsize, $vsize, RGB);
     
     # Vorder- und Hintergrundfarbe setzen
     gimp_palette_set_foreground($frcolor);
     gimp_palette_set_background($bgcolor);
     
     # neue Ebene erzeugen
     my $layer1 = gimp_layer_new($img, $hsize, $vsize,
                     RGB_IMAGE, "Ebene 1", 100, 0);
     my $layer2 = gimp_layer_new($img, $hsize, $vsize,
                     RGBA_IMAGE, "Ebene 2", 100, 0);
     
     # Ebene dem Bild hinzufügen
     gimp_image_add_layer($img, $layer1, -1);
     gimp_image_add_layer($img, $layer2, -1);
     gimp_edit_clear($layer2);
     
     # Ebene 2 mit Rahmenfarbe füllen
     gimp_edit_fill($layer2, FG_IMAGE_FILL);
     
     # Ebene 1 mit Hintergrundfarbe füllen
     gimp_edit_fill($layer1, BG_IMAGE_FILL);
     
     # eine 15 Pixel vom Rand entfernte Auswahl wählen
     gimp_selection_all($img);
     gimp_selection_shrink($img, 15);
     
     # Auswahl ausschneiden
     gimp_edit_cut($layer2);
     
     # Ebene 2 kopieren
     my $layer3 = gimp_layer_copy($layer2, 0);
     
     # Kopierte Ebene dem Bild hinzufügen
     gimp_image_add_layer($img, $layer3, -1);
     
     # Ebene 2: minimale Helligkeit, maximaler Kontrast
     gimp_brightness_contrast($layer2, -127, 127);
     
     # Ebene 2: Weichzeichnen
     plug_in_gauss_iir2(0, $layer2, 15, 15);
     
     # Schatten nach rechts-unten verschieben
     gimp_layer_translate($layer2, 7, 7);
     
     # Deckkraft der Schatten-Ebene (Ebene 2) verringern
     gimp_layer_set_opacity($layer2, 60);
     
     # Text-Farbe wählen
     gimp_palette_set_foreground('#000000');
     
     # Text erstellen
     my $textlayer = gimp_text_fontname($img, -1, 20, 20,
                        $text, 1, 1, $vsize - 40, 0, $font);
     
     # Text zentrieren
     perl_fu_center_layer($img, $textlayer);
     
     # Bild zusammenfügen (sichtbare Ebenen)
     $layer1 = gimp_image_flatten($img);
     
     # Bild zurückgeben
     return $img;
 }
 
 register
   # Name
   "Button",
   # Beschreibung
   "Ein einfacher Button mit Schlagschatten",
   # Hilfetext
   "Erzeugt einen Button, dessen Rahmen einen
   Schatten auf das Innere wirft.\n
   Achtet darauf, dass die Breite für den
   Text reicht!",
   # Autoren-Name
   "Michael Pradel",
   # Copyright
   "Michael Pradel",
   # Datum
   "07-2002",
   # Pfad
   "<Toolbox>/Xtns/Perl-Fu/Button",
   # Bildarten
   "*",
   # zu übergebene Werte
   [
    [PF_INT, "Bildbreite", "Bildbreite", 300],
    [PF_INT, "Bildhoehe", "Bildhoehe", 70],
    [PF_COLOR, "HG-Farbe", "Hintergrundfarbe", '#71a5f2'],
    [PF_COLOR, "Rahmen-Farbe", "Rahmenfarbe", '#9d1912'],
    [PF_FONT, "Schrift", "Schrift",
    '-b&h-lucida-medium-r\normal-*-*-190-*-*-p-*-iso10646-1'],
    [PF_STRING, "Text", "Text", "Ein Button"]
   ],
   # Aufruf der Subroutine
   \&button;
 
 exit main();

Der Register-Teil ähnelt dem aus dem ersten Beispiel, allerdings werden mehr Werte übergeben. Zu Beginn der Subroutine werden wir gehabt zunächst die übergebenen Werte aus dem Array @_ in einzelne Variablen kopiert (Zeile 8). Anschließend erzeugen wir ein neues Bild und setzen die Vorder- und Hintergrundfarbe wie vom Benutzer angegeben.

Nun erzeugen wir 2 neue Ebene, wobei die zweite vom Typ RGBA_IMAGE, statt wie bisher RGB_IMAGE sein muss (Zeile 19). Das zusätzliche A bedeutet das ein Alpha-Kanal existiert, also Transparenz möglich ist. Die neuen Ebenen fügen wir unserem Bild hinzu und wenden gimp_edit_clear auf die zweite Ebene an, so dass diese vollständig transparent ist (Zeile 24). Jetzt füllen wir die Ebenen mit je einer Farbe und wählen eine Auswahl, welche alles bis auf einen 15 Pixel breiten Rand umfasst. Hierzu wählen wir zunächst alles (Zeile 33), und verkleinern die Auswahl anschließend mit gimp_selection_shrink. Diese Auswahl schneiden wir auf Ebene 2 weg, so dass wir folgenden Zwischenstand erhalten:

Nun folgt das wichtigste an diesem Beispiel: der Schatten: Ebene 2 (also die mit dem Rahmen) kopieren wir, nennen sie $layer3 und fügen sie dem Bild hinzu. Mittels gimp_brightness_contrast setzen wir die Helligkeit auf das Minimum und den Kontrast auf das Maximum, so dass die kopierte Ebene dunkler wird (Zeile 46). Der Schatten soll natürlich nicht so scharf sein, weswegen wir ihn mit plug_in_gauss_iir2 weichzeichnen (Zeile 49). Zwischenstand:

Der Schatten befindet sich jetzt genau unter dem Rahmen, was uns nicht gefällt. Wir verschieben ihn deshalb mit gimp_layer_translate je 7 Pixel nach rechts und unten (Zeile 52). Anschließend verringern wir die Deckkraft der Schatten-Ebene ($layer3) auf 60%. Alles was uns jetzt noch zum fertigen Button fehlt ist der Text. Diesen machen wir schwarz (wer eine andere Farbe bevorzugt kann dies gern ändern, man kann es aber beispielsweise auch dem Benutzer überlassen die richtige zu wählen), stellen also die Vordergrundfarbe auf #000000 (Zeile 58).

Der Text kommt (wie immer in Gimp) in eine eigene Ebene ($textlayer). Was die an gimp_text_fontname übergebenen Parameter bedeuten empfehle ich wie bei allen anderen Funktionen auch im PDB-Explorer nachzuschauen. Nun zentrieren wir den Text noch, wozu wir die Ebene-Zentrieren-Funktion nehmen können, da der Text ja in einer eigenen Ebene ist und diese genau die Größe unseres Textes hat. Zum Schluss fügen wir alle sichtbaren Ebenen (also bei uns alle die es gibt) zusammen (Zeile 66). Das Endergebnis schaut je nach Einstellung dann z.B. so aus:

       

Weitere Quellen

Das wohl wichtigste Werkzeug ist zweifelsohne der PDB-Explorer (in Gimp im Xtns-Menü zu finden). Außerdem gibt es Manpages zu den Perl-Modulen:

Diese sind unter goof.com/pcg/marc/gimp.html auch online verfügbar. Allgemeine Infos zu Gimp gibt es unter gimp.org, hier könnt ihr auch das Gimp Manual runterladen.